home *** CD-ROM | disk | FTP | other *** search
/ Collection of Tools & Utilities / Collection of Tools and Utilities.iso / asmutil / alib10.zip / EDREC.ASM < prev    next >
Assembly Source File  |  1994-04-07  |  32KB  |  1,309 lines
  1. ;***************************** EDREC.ASM   **********************************
  2. PAGE  70,132
  3. COMMENT 
  4.                               EDREC (Edit Records)
  5.                               Version 1.0
  6.                               --------------------
  7.  
  8.  
  9.      Purpose
  10.      -------
  11.  
  12.      EDREC is both a sample program and ALIB utility program.  Files
  13.      created by EDREC use ALIB database format which is also used by
  14.      hyper message and error displays.  This greatly simplifies the
  15.      process of creating a file of error messages or help screens.
  16.  
  17.      Using EDREC
  18.      -----------
  19.  
  20.      EDREC can be started by typing EDREC or by typing EDREC followed
  21.      with a file name.  If the file exists, EDREC will display the first
  22.      record and wait for input.  If the file does not exist the record
  23.      window will be blank.
  24.  
  25.      The data entered using EDREC is probably going to be displayed in
  26.      a window someday, so the window size should be selected to make
  27.      data entry easier.  The record window size is set by the "Config"
  28.      menu option.
  29.  
  30.      After setting the window size, select "Edit" to add or modify
  31.      records.
  32.      
  33.      Database Format
  34.      ---------------
  35.  
  36.      EDREC creates records in a window which can be configured to any size.
  37.      Each record is variable length and terminated by a null (hex 00 char).
  38.  
  39.      Compiling
  40.      ---------
  41.  
  42.      The MASM & LINK commands needed to build EDREC.EXE are:
  43.         masm edrec;
  44.         link edrec,edrec,,alib.lib;
  45.  
  46.      
  47. 
  48.  
  49.     include    mac.inc
  50.     include    common.inc
  51. ;-----------------------------------------------------------------------------
  52.     extrn    library_setup:far
  53.     extrn    lib_error_handler:far
  54.     extrn    error_handler:far
  55.     extrn    clear_screen:far
  56.     extrn    display_string:far
  57.     extrn    display_string_fill:far
  58.     extrn    put_crt_blk:far
  59.     extrn    repeat_put_crt:far
  60.     extrn    BREAK_KEY_INTERCEPT:far
  61.     extrn    change_path:far
  62.     extrn    MENU_SYSTEM:far
  63.     extrn    change_setup:far
  64.     extrn    restore_path:far
  65.     extrn    find_home_path:far
  66.     extrn    library_terminate:far
  67.     extrn    BREAK_KEY_RESTORE:far
  68.     extrn    parse_first:far
  69.     extrn    expand_filename:far
  70.     extrn    get_string:far
  71.     extrn    qget_string:far
  72.     extrn    DEC_STR_TO_WORD:far
  73.     extrn    WORD_TO_DEC_CRT:far
  74.     extrn    get_setup:far
  75.     extrn    save_window:far
  76.     extrn    restore_window:far
  77.     extrn    draw_box:far
  78.     extrn    box_shrink:far
  79.     extrn    window_string:far
  80.     extrn    yes_or_no:far
  81.     extrn    flush_keyboard:far
  82.     extrn    set_lib_colors:far
  83.     extrn    dbase_init:far
  84.     extrn    DBASE_READ:far
  85.     extrn    dbase_read_next:far
  86.     extrn    dbase_read_prev:far
  87.     extrn    dbase_append:far
  88.     extrn    dbase_replace:far
  89.     extrn    dbase_insert:far
  90.     extrn    DBASE_REMOVE:far
  91.     extrn    dbase_close:far    
  92.     extrn    window_edit:far
  93.     extrn    window_cstring:far
  94.     extrn    strlen3:far
  95.     extrn    qwarn:far
  96.     extrn    to_upper:far
  97.     extrn    message:far
  98. ;------------------------------------------------------------------------------
  99. code        segment para public 'CODE'
  100.         assume    cs:code, ds:code
  101. ;-----------------------------------------------------------------------------
  102. ; 
  103. edit1_msg    db    ' Current Record #',0
  104. edit3_msg    db    '(alt-H) for help ',0
  105. append_msg    db    'append',0 
  106. insert_msg    db    'insert',0
  107. modify_msg    db    'modify',0
  108. exit_msg    db    'EDREC exiting, do you wish to save the changes in memory? (Y/n)',0
  109. pspseg        dw    0
  110. lib_info_ptr    dw    0
  111. lib_info_seg    dw    0
  112.  
  113. current_operation    db    0    ;0=none 1=append 2=insert 3=replace
  114. current_record        dw    1
  115. current_record_ptr    dw    0
  116. current_Record_len    dw    0
  117. null_file_flag        db    0    ;0=file empty
  118.  
  119. file_asciiz        db    40 dup (0)
  120.  
  121. box_size        label    word
  122. box_cols        db    50    ;columns
  123. box_rows        db    5    ;rows
  124.  
  125. box_location        label    word
  126.             db    14    ;column
  127.             db    5    ;row
  128.  
  129. dirty_flag        db    0    ;1=changes have been made
  130. saved_flag        db    0    ;1=file has been saved
  131.  
  132. buffer_size    equ    1000        ;largest record size
  133. buffer            db    buffer_size dup (0)
  134. buffer_ptr        dw    buffer
  135. cursor_position        dw    0
  136.  
  137. file_create_flag    db    0    ;1=create is needed
  138. string1            db    3 dup (0)
  139. string2            db    3 dup (0)
  140.  
  141. help_asciiz        db    'EDREC.HLP',0
  142.  
  143. null_file_msg        db    'The database does not contain any records'
  144.             db    ' select the EDIT and APPEND options to add'
  145.             db    ' records, or CONFIG option to change setup.'
  146.             db    0dh,0ah,0dh,0ah,'Press any key to continue',0
  147. not_yet_msg        db    'This feature not implemented at present.  '
  148.             db    ' Press any key to continue',0
  149. ;-----------------------------------------------------------------------------
  150. start:
  151.     cli
  152.     mov    cs:pspseg,es    ;save PSP segment
  153.     mov    ax,cs        ;get CODE segment
  154.     mov    ss,ax
  155.     mov    ds,ax
  156.     mov    es,ax
  157.     mov    sp,offset stack_
  158.     sti
  159.     
  160. ; next, release memory beyond the end of the program
  161. ; The  definition for ZSEG marks the
  162. ; end of the program's code, data and stack area.
  163. ; When linking be sure ZSEG is at the end of the program.
  164.  
  165.     mov    ax,zseg
  166.  
  167.     mov    bx,cs:pspseg        ;
  168.     mov    es,bx
  169.     sub    bx,ax
  170.     neg    bx            ; size of program in paragraphs
  171.     mov    ah,4Ah            ; resize memory block
  172.     int    21h
  173.  
  174.     mov    ax,cs
  175.     mov    es,ax
  176. ;
  177. ; check if enough memory free to run program
  178. ;
  179.     mov    ax,pspseg        ;pass psp segment to setup
  180.     mov    bx,0            ;number of floating point variables
  181.     call    library_setup
  182.     mov    lib_info_ptr,si        ;save ptr to library info block
  183.     mov    lib_info_seg,es         ; see COMMON.INC or LIBRARY_SETUP
  184.     cmp    ax,128
  185.     jae    got_enough_mem        ;jmp if 128k of memory avail
  186.     mov    al,7
  187.     mov    ah,fatal_return
  188.     call    lib_error_handler
  189.     jmp    exitx
  190.     
  191. got_enough_mem:
  192. ;
  193. ; clear the screen and display signon
  194. ;
  195.     mov    ah,app_text_color
  196.     mov    al,' '
  197.     call    clear_screen
  198. ;
  199. ; display copyright message
  200. ;
  201.     mov    si,offset copyright_msg
  202.     mov    ah,app_text_color
  203.     mov    dx,1008h        ;display row 16 column xx
  204.     call    display_string    
  205.     
  206.     
  207. ; prevent an unintended program crash; trap Ctrl+Break, Ctrl+C and
  208. ; Ctrl+Alt+Del key combinations
  209.  
  210. ;    call    BREAK_KEY_INTERCEPT
  211.  
  212. ;
  213. ; switch to home directory
  214. ;
  215.     push    es
  216.     call    find_home_path
  217.     mov    bx,di
  218.     call    change_path
  219.     pop    es
  220.     jnc    path_changed
  221.     mov    al,6
  222.     mov    ah,fatal_return
  223.     call    lib_error_handler
  224.     jmp    exit2
  225. path_changed:
  226.     call    read_setup
  227.     call    establish_defaults    ;set colors & see if config file avail
  228.     call    ck_for_filename
  229. ;
  230. ; read the file (initialize the database)
  231. ;
  232. init_database:
  233.     mov    dx,offset file_asciiz
  234.     call    dbase_init
  235.     mov    es,bx            ;move selector to es:
  236. ;
  237. ; if file does not exist, then ask if create ok
  238. ;
  239.     cmp    al,1            ;check if file opened ok
  240.     jbe    clear_and_display
  241.     jmp    exit            ;jmp if error opening file
  242. ;
  243. ; clear the screen and display the box
  244. ;
  245. clear_and_display:
  246.     mov    ah,_msg_text_color
  247.     mov    al,' '
  248.     call    clear_screen
  249.     mov    dx,box_location
  250.     mov    bx,box_size
  251.     mov    ah,_msg_text_color
  252.     mov    al,0            ;single line frame
  253.     call    draw_box
  254. ;
  255. ; fill box with record info.
  256. ;
  257.     mov    dx,current_record
  258.     call    DBASE_READ
  259.     cmp    al,0
  260.     je    show_rec        ;jmp if record found
  261.     cmp    dx,1            ;check if this is record 1
  262.     jne    show_rec        ;jmp if database has records
  263. ;
  264. ; current database is empty
  265. ;
  266. null_file:
  267.     apush    ds,es
  268.     mov    ax,cs
  269.     mov    ds,ax
  270.     mov    es,ax
  271.     mov    ah,cs:_msg_text_color
  272.     mov    al,0
  273.     mov    bx,0840h
  274.     mov    dx,0808h
  275.     mov    cx,1
  276.     mov    si,offset null_file_msg
  277.     mov    bp,msg_save_win+msg_restore_win+msg_anykey+msg_disp+msg_ram
  278.     call    message
  279.     apop    es,ds        
  280.     jmp    menu1            ;jmp if empty database
  281. ;
  282. ; this record is not present in the data base, ask for instructions
  283. ;
  284.  
  285. ;
  286. ; fill the box with current record contents
  287. ;   es:si point at data for display
  288. ;      cx = record length
  289. ;
  290. show_rec:
  291.     mov    null_file_flag,1    ;specify database has data
  292.     call    move_to_buffer
  293. ;
  294. ; setup to display buffer
  295. ;
  296. display_buffer:        
  297.     mov    bx,box_size
  298.     mov    dx,box_location
  299.     call    box_shrink
  300.     mov    ah,_msg_text_color    
  301.     mov    si,offset buffer
  302.     push    di
  303.     mov    di,0
  304.     call    window_cstring
  305.     pop    di
  306. ;
  307. ; display status line with record#
  308. ;
  309.     call    show_rec_status
  310. ;
  311. ; show menu bar and wait for selection
  312. ;
  313. menu1:    mov    bx,offset menu1_def
  314.     mov    ah,08h+20h        ;restore bar & return unknown keys
  315.     call    MENU_SYSTEM
  316.     cmp    cl,1            ;check if process key
  317.     jne    menu1_d2        ;jmp if not process hit
  318.     jmp    ax
  319.     jmp    menu1            ;go do it again
  320. menu1_d2:
  321.     cmp    cl,4            ;check if abort key
  322.     je    quit_j
  323.     cmp    cl,2
  324.     jne    menu1            ;jmp if unknown mouse or no key press
  325.     cmp    al,51h
  326.     je    pgdn_j
  327.     cmp    al,49h
  328.     je    pgup_j
  329.     jmp    menu1
  330.     
  331. quit_j:    jmp    quit    
  332. p